UrlsWorker/build.gradle

plugins {
    id 'org.springframework.boot' version '2.7.12'
    id 'io.spring.dependency-management' version '1.1.0'
    id 'java'
}

group = 'eu.openaire.urls_worker'
version = '1.0.0-SNAPSHOT'
sourceCompatibility = '1.8'

repositories {
    mavenCentral()
    flatDir {
        dirs 'libs'
    }
}

dependencies {
    runtimeOnly "org.springframework.boot:spring-boot-devtools"

    implementation("org.springframework.boot:spring-boot-starter-web")
    implementation("org.springframework.boot:spring-boot-starter-security")
    implementation("org.springframework.boot:spring-boot-configuration-processor")
    implementation("org.springframework.security:spring-security-core")
    implementation("org.springframework.security:spring-security-web")
    implementation("org.springframework.security:spring-security-config")

    implementation 'org.projectlombok:lombok:1.18.26'

    //implementation group: 'io.jsonwebtoken', name: 'jjwt-api', version: '0.11.5'    // Use this in case we use auth-tokens later on.

    // Enable the validation annotations.
    //implementation group: 'jakarta.validation', name: 'jakarta.validation-api', version: '3.0.2'

    implementation ("eu.openaire:publications_retriever:1.0-SNAPSHOT") {
        exclude group: 'ch.qos.logback', module: 'logback-core'
        exclude group: 'ch.qos.logback', module: 'logback-classic'
        exclude group: 'org.slf4j', module: 'slf4j-api'
        exclude group: 'io.minio'   // This is not used in the Worker, since it's the Controller which uploads the full-texts to S3. It also includes an older "commons-compress" version which causes problems.
    }

    implementation group: 'com.google.guava', name: 'guava', version: '31.1-jre'

    implementation 'org.apache.commons:commons-compress:1.23.0'
    implementation 'com.github.luben:zstd-jni:1.5.5-3'  // Even though this is part of the above dependency, it is needed separately as well, specifically here, in the Worker.

    testImplementation 'org.springframework.security:spring-security-test'
    testImplementation "org.springframework.boot:spring-boot-starter-test"
}

configurations {
    // Eliminates logback from other dependencies.
    all*.exclude group: 'ch.qos.logback'
}

// Set increased lower and upper limits for the java-execution.
tasks.withType(JavaExec).configureEach {
    jvmArgs = ['-Xms512m', '-Xmx8g']
}

test {
    useJUnitPlatform()
}