AriadnePlus/dnet-ariadneplus-graphdb-pu.../src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/PP/ordered_sparql_insert_pp.sp...

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks> {
        ?s aocat:was_modified ?issued .
    }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks>
WHERE {
    ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
    ?s aocat:was_issued ?issued .
    MINUS {
        ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
        ?s aocat:was_issued ?issued .
        ?s aocat:was_modified ?modified .
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks> {
          ?s	aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> .
          <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Concept> .
          <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> skos:prefLabel "collection"
        }
    }
    WHERE {
        GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks> {
            ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
            MINUS {
                ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
                ?s	aocat:has_type ?t .
            }
        }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks> {
      ?s	aocat:has_temporal_coverage <https://ariadne-infrastructure.eu/aocat/Time-Span/NOTPROVIDED> .
      <https://ariadne-infrastructure.eu/aocat/Time-Span/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Temporal_Region> .
      <https://ariadne-infrastructure.eu/aocat/Time-Span/NOTPROVIDED> rdfs:label "Not provided" .

    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks> {
        ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
        MINUS {
            ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
            ?s	aocat:has_temporal_coverage ?tc .
        }
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks> {
        ?nativeLabel skos:prefLabel ?origTemporalNativePeriodName .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks> {
        ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
    	?s aocat:has_temporal_coverage  ?temporalNative .
        ?temporalNative aocat:has_native_period ?nativeLabel .
        ?nativeLabel rdfs:label ?origTemporalNativePeriodName .
        MINUS {
            ?nativeLabel skos:prefLabel ?origTemporalNativePeriodName .
        }
    }
};

PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
INSERT {
 GRAPH <https://ariadne-infrastructure.eu/ariadneplus::pp::aatplus> {
     ?record aocat:has_derived_subject ?aat_subject .
 }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::aat>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks>
WHERE {
     {
         ?record aocat:has_native_subject ?native_subject .
         ?aat_native_subject skos:exactMatch ?aat_subject	.
         bind (IRI(replace( str(?aat_native_subject), "PP", "University%20of%20Patras")) as ?patched_aat_native_subject)
         filter(?native_subject=?patched_aat_native_subject)
     }
     union
     {
        ?record aocat:has_native_subject ?native_subject .
        ?aat_native_subject skos:broadMatch ?aat_subject	.
        bind (IRI(replace( str(?aat_native_subject), "PP", "University%20of%20Patras")) as ?patched_aat_native_subject)
        filter(?native_subject=?patched_aat_native_subject)
     }
     union
     {
        ?record aocat:has_native_subject ?native_subject .
        ?aat_native_subject skos:closeMatch ?aat_subject	.
        bind (IRI(replace( str(?aat_native_subject), "PP", "University%20of%20Patras")) as ?patched_aat_native_subject)
        filter(?native_subject=?patched_aat_native_subject)
     }
     union
     {
        ?record aocat:has_native_subject ?native_subject .
        ?aat_native_subject skos:narrowMatch ?aat_subject	.
        bind (IRI(replace( str(?aat_native_subject), "PP", "University%20of%20Patras")) as ?patched_aat_native_subject)
        filter(?native_subject=?patched_aat_native_subject)
     }
};

PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
 PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
 PREFIX time: <http://www.w3.org/2006/time#>
 INSERT {
     GRAPH <https://ariadne-infrastructure.eu/ariadneplus::pp::periodoplus> {
         ?temporal aocat:has_period ?native_period .
         ?temporal aocat:from ?from .
         ?temporal aocat:until ?until .
     }
 }
 WHERE {
 	GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks> {
       ?temporal aocat:has_native_period ?native_period .
       ?native_period skos:prefLabel ?native_label .
       ?temporal aocat:from ?from .
       ?temporal aocat:until ?until .
   }
 };

 PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
  PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
  PREFIX time: <http://www.w3.org/2006/time#>
  INSERT {
      GRAPH <https://ariadne-infrastructure.eu/ariadneplus::pp::periodo> {
          ?native_period skos:prefLabel ?native_label .
      }
  }
  WHERE {
  	GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::pp::fieldworks> {
        ?temporal aocat:has_native_period ?native_period .
        ?native_period skos:prefLabel ?native_label .
        ?temporal aocat:from ?from .
        ?temporal aocat:until ?until .
    }
  };