AriadnePlus/dnet-ariadneplus-graphdb-publisher/src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/ZRC/ordered_sparql_insert_zrc_arkas.sparql

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/ariadneplus::zrc_arkas::aatplus> {
        ?record aocat:has_derived_subject ?aat .
    }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::aat>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::sites>
WHERE {
        {
            ?record aocat:has_native_subject ?native_subject .
            ?native_subject skos:exactMatch ?aat	.
        }
        union
        {
            ?record aocat:has_native_subject ?native_subject .
            ?native_subject skos:broadMatch ?aat	.
        }
        union
        {
            ?record aocat:has_native_subject ?native_subject .
            ?native_subject skos:closeMatch ?aat	.
        }
        union
        {
            ?record aocat:has_native_subject ?native_subject .
            ?native_subject skos:narrowMatch ?aat	.
        }
};

PREFIX dcterms: <http://purl.org/dc/terms/>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/ariadneplus::zrc_arkas::periodo> {
            ?periodO ?pred ?o .
            ?o ?pred2 ?o2 .
            ?o2 ?pred3 ?o3 .
        }
    }
    WHERE {
        GRAPH <https://ariadne-infrastructure.eu/ariadne/periodo> {
            ?periodO dcterms:spatial <http://www.wikidata.org/entity/Q215> .
            ?periodO ?pred ?o .
            optional {
                ?o ?pred2 ?o2 .
                optional {
                    ?o2 ?pred3 ?o3 .
                }
            }
        }
    };
    
PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
 PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
 PREFIX time: <http://www.w3.org/2006/time#>
 PREFIX dcterms: <http://purl.org/dc/terms/>
 INSERT {
     GRAPH <https://ariadne-infrastructure.eu/ariadneplus::zrc_arkas::periodoplus> {
         ?temporal aocat:has_period ?periodO .
         ?temporal aocat:from ?temporalFrom .
         ?temporal aocat:until ?temporalUntil .
     }
 }
 WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::sites> {
       ?temporal aocat:has_native_period ?native_period .
        ?native_period skos:prefLabel ?native_label .
        optional {
            GRAPH <https://ariadne-infrastructure.eu/ariadneplus::zrc_arkas::periodo> {
                ?periodO skos:altLabel ?native_label .
                ?periodO time:intervalStartedBy / time:hasDateTimeDescription / time:year ?temporalFrom .
                ?periodO time:intervalFinishedBy / time:hasDateTimeDescription / time:year ?temporalUntil .
            }
       }
   }
 };

PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
 insert
 {
     GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::sites> {
     ?s aocat:was_issued ?year .
     }
 }
 WHERE
 {
     GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::sites> {
         ?s rdf:type aocat:AO_Individual_Data_Resource .
   ?s aocat:was_issued ?o .
         FILTER(contains(str(?o), "."))
         BIND( strdt( strafter(strafter(str(?o),"."),".") , xsd:datetime)   AS ?year)
     }
 };

PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
 delete {
     GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::sites> {
      ?s aocat:was_issued ?o .
     }
 }
 where {
     GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::sites> {
     ?s rdf:type aocat:AO_Individual_Data_Resource .
         ?s aocat:was_issued ?o .
        FILTER(contains(str(?o), "."))
     }

 };

 PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
 PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
 PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
 PREFIX  rdfs: <http://www.w3.org/2000/01/rdf-schema#>
 PREFIX dcterms: <http://purl.org/dc/terms/>
 PREFIX dc: <http://purl.org/dc/elements/1.1/>
 PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
 PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
  insert
  {
      GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::sites> {
      ?s aocat:was_modified ?year .
      }
  }
  WHERE
  {
      GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::sites> {
          ?s rdf:type aocat:AO_Individual_Data_Resource .
    ?s aocat:was_modified ?o .
          FILTER(contains(str(?o), "."))
          BIND( strdt( strafter(strafter(str(?o),"."),".") , xsd:datetime)   AS ?year)
      }
  };

 PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
 PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
 PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
 PREFIX  rdfs: <http://www.w3.org/2000/01/rdf-schema#>
 PREFIX dcterms: <http://purl.org/dc/terms/>
 PREFIX dc: <http://purl.org/dc/elements/1.1/>
 PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
 PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
  delete {
      GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::sites> {
       ?s aocat:was_modified ?o .
      }
  }
  where {
      GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::zrc_arkas::sites> {
      ?s rdf:type aocat:AO_Individual_Data_Resource .
          ?s aocat:was_modified ?o .
         FILTER(contains(str(?o), "."))
      }

  };