AriadnePlus/dnet-ariadneplus-graphdb-publisher/src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/IAVP/ordered_sparql_insert_IAVP.sparql

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::0> {
        ?record aocat:was_issued ?issued .
        ?record aocat:was_modified ?modified .
        ?record aocat:has_contributor ?contributor .
        ?contributor aocat:has_name ?contrib .
        ?record aocat:has_responsible ?legalResponsible .
        ?legalResponsible aocat:has_name ?resp .
        ?record aocat:has_owner ?owner .
        ?owner aocat:has_name ?own .
        ?record aocat:has_publisher ?publisher .
        ?publisher aocat:has_name ?pub .
        ?record aocat:has_access_rights ?accessRights .
        ?record aocat:has_ARIADNE_subject ?archeologicalResourceType .
        ?archeologicalResourceType skos:prefLabel ?alabel .
        ?record aocat:has_language ?lang .
        ?lang skos:prefLabel ?langL
    }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::0>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::collection>
WHERE {
	?record aocat:is_part_of ?collection .
    ?collection aocat:was_issued ?issued .
    ?collection aocat:was_modified ?modified .
    ?collection aocat:has_contributor ?contributor .
    ?contributor aocat:has_name ?contrib .
    ?collection aocat:has_responsible ?legalResponsible .
    ?legalResponsible aocat:has_name ?resp .
    ?collection aocat:has_owner ?owner .
    ?owner aocat:has_name ?own .
    ?collection aocat:has_publisher ?publisher .
    ?publisher aocat:has_name ?pub .
    ?collection aocat:has_access_rights ?accessRights .
    ?collection aocat:has_ARIADNE_subject ?archeologicalResourceType .
    ?archeologicalResourceType skos:prefLabel ?alabel .
    ?collection aocat:has_language ?lang .
    ?lang skos:prefLabel ?langL
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::0> {
        ?s	aocat:has_creator <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> .
        <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Agent> .
        <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdfs:label "Not provided" .
        <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> aocat:has_name "Not provided" .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::0> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            ?s	aocat:has_creator ?creator .
        }
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/ariadneplus::iavp::aatplus> {
        ?record aocat:has_derived_subject ?aat .
    }
}
WHERE {
        GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::0> {
         ?record aocat:has_native_subject ?ns.
            GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::aat> {
                {
                ?ns skos:closeMatch ?aat .
                }
                union
                {
                ?ns skos:exactMatch ?aat .
                }
                union
                {
                ?ns skos:narrowMatch ?aat .
                }
                union
                {
                ?ns skos:broadMatch ?aat .
                }
            }
        }
};

PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
 PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
 PREFIX time: <http://www.w3.org/2006/time#>
 INSERT {
     GRAPH <https://ariadne-infrastructure.eu/ariadneplus::iavp::periodoplus> {
         ?temporal aocat:has_period ?native_period .
         ?temporal aocat:from ?from .
         ?temporal aocat:until ?until .
     }
 }
 WHERE {
 	GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::0> {
       ?temporal aocat:has_native_period ?native_period .
       ?native_period skos:prefLabel ?native_label .
       ?temporal aocat:from ?from .
       ?temporal aocat:until ?until .
   }
 };

 PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
  PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
  PREFIX time: <http://www.w3.org/2006/time#>
  INSERT {
      GRAPH <https://ariadne-infrastructure.eu/ariadneplus::iavp::periodo> {
          ?native_period skos:prefLabel ?native_label .
      }
  }
  WHERE {
  	GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::0> {
        ?temporal aocat:has_native_period ?native_period .
        ?native_period skos:prefLabel ?native_label .
        ?temporal aocat:from ?from .
        ?temporal aocat:until ?until .
    }
  };
  
  PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
  PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
  INSERT {
      GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::0> {
            ?s	aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> .
            <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Concept> .
            <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> skos:prefLabel "provided record"
          }
      }
      WHERE {
          GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::0> {
              ?s rdf:type aocat:AO_Individual_Data_Resource .
              MINUS {
              ?s rdf:type aocat:AO_Individual_Data_Resource .
                  ?s	aocat:has_type ?t .
              }
          }
  };