AriadnePlus/dnet-ariadneplus-graphdb-publisher/src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/LNEC/ordered_sparql_insert_LNEC.sparql

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::site> {
        ?record aocat:has_owner ?owner .
        ?owner aocat:has_name ?own .
        ?record aocat:has_responsible ?legalResponsible .
        ?legalResponsible aocat:has_name ?resp .
    }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::site>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::CollectionInfo>
WHERE {
	?record aocat:is_part_of ?collection .
	?collection aocat:has_owner ?owner .
	?owner aocat:has_name ?own .
	?collection aocat:has_responsible ?legalResponsible .
    ?legalResponsible aocat:has_name ?resp .
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::site> {
        ?s	aocat:has_creator <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> .
        <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Agent> .
        <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdfs:label "Not provided" .
        <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> aocat:has_name "Not provided" .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::site> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            ?s	aocat:has_creator ?creator .
        }
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
  PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
  INSERT {
      GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::site> {
            ?s	aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> .
            <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Concept> .
            <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> skos:prefLabel "provided record"
          }
      }
      WHERE {
          GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::site> {
              ?s rdf:type aocat:AO_Individual_Data_Resource .
              MINUS {
              ?s rdf:type aocat:AO_Individual_Data_Resource .
                  ?s	aocat:has_type ?t .
              }
          }
  };

  PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
  PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
  INSERT {
      GRAPH <https://ariadne-infrastructure.eu/ariadneplus::lnec::aatplus> {
          ?record aocat:has_derived_subject ?aat .
      }
  }
  WHERE {
          GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::site> {
               ?record aocat:has_native_subject ?ns.
                  GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::aat> {
                      {
                      ?ns skos:closeMatch ?aat .
                      }
                      union
                      {
                      ?ns skos:exactMatch ?aat .
                      }
                      union
                      {
                      ?ns skos:narrowMatch ?aat .
                      }
                      union
                      {
                      ?ns skos:broadMatch ?aat .
                      }
                  }
              }
  };
  
  PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
  PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
  PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  PREFIX owl: <http://www.w3.org/2002/07/owl#>
  PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
  PREFIX time: <http://www.w3.org/2006/time#>
  PREFIX periodo: <http://n2t.net/ark:/99152/p0v#>
  INSERT {
   GRAPH <https://ariadne-infrastructure.eu/ariadneplus::lnec::periodoplus> {
       ?temporal aocat:has_period ?periodO .
       ?temporal aocat:from ?temporalFrom .
       ?temporal aocat:until ?temporalUntil .
   }
  }
  WHERE {
   GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::site> {
         ?temporal aocat:has_native_period ?native_period .
          ?native_period skos:prefLabel ?native_label .
          optional {
              GRAPH <https://ariadne-infrastructure.eu/ariadneplus::lnec::periodo> {
                  ?periodO skos:altLabel ?native_label .
                  ?periodO time:intervalStartedBy / time:hasDateTimeDescription / time:year ?temporalFrom .
                  ?periodO time:intervalFinishedBy / time:hasDateTimeDescription / time:year ?temporalUntil .
              }
         }
     }
  };
  
  PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
  PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  INSERT {
      GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::site> {
        ?s	aocat:has_spatial_coverage <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> .
        <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Spatial_Region> .
        <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> rdfs:label "Name not provided" .
        <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> aocat:has_place_name "Name not provided" .
      }
  }
  WHERE {
      GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::site> {
          ?s rdf:type aocat:AO_Individual_Data_Resource .
          MINUS {
              ?s rdf:type aocat:AO_Individual_Data_Resource .
              ?s	aocat:has_spatial_coverage ?spatialRegion .
              ?spatialRegion  aocat:has_place_name ?placeName .
          }
      }
  };