D-Net
/
AriadnePlus
4
0
Fork 0
Code Issues Pull Requests Releases Wiki Activity
AriadnePlus/dnet-ariadneplus-graphdb-pu.../src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/NARA/ordered_sparql_insert_nara....

377 lines
16 KiB
SPARQL
Raw Blame History

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> .
<https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Concept> .
<https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> skos:prefLabel "collection"
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
MINUS {
?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
?s aocat:has_type ?t .
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:has_access_rights "Not provided" .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
MINUS {
?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
?s aocat:has_access_rights ?ar .
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:has_creator <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> .
<https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Agent> .
<https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdfs:label "Not provided" .
<https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> aocat:has_name "Not provided" .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s rdf:type aocat:AO_Individual_Data_Resource .
MINUS {
?s rdf:type aocat:AO_Individual_Data_Resource .
?s aocat:has_creator ?creator .
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?record aocat:has_publisher ?publisher .
?record aocat:has_access_rights ?accessRights .
?record aocat:has_access_policy ?access_policy .
?record aocat:has_ARIADNE_subject ?archeologicalResourceType .
}
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport>
WHERE {
?record aocat:is_part_of ?collection .
?collection aocat:has_publisher ?publisher .
?collection aocat:has_access_rights ?accessRights .
?collection aocat:has_access_policy ?access_policy .
?collection aocat:has_ARIADNE_subject ?archeologicalResourceType .
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:has_access_rights "Not provided" .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s rdf:type aocat:AO_Individual_Data_Resource .
MINUS {
?s rdf:type aocat:AO_Individual_Data_Resource .
?s aocat:has_access_rights ?ar .
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:has_ARIADNE_subject <https://ariadne-infrastructure.eu/aocat/Concept/AO_Subject/NOTPROVIDED> .
<https://ariadne-infrastructure.eu/aocat/Concept/AO_Subject/NOTPROVIDED> skos:prefLabel "Not provided" .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s rdf:type aocat:AO_Individual_Data_Resource .
MINUS {
?s rdf:type aocat:AO_Individual_Data_Resource .
?s aocat:has_ARIADNE_subject ?ariadneSubject .
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:has_publisher <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> .
<https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Agent> .
<https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdfs:label "Not provided" .
<https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> aocat:has_name "Not provided" .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s rdf:type aocat:AO_Individual_Data_Resource .
MINUS {
?s rdf:type aocat:AO_Individual_Data_Resource .
?s aocat:has_publisher ?agent .
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:has_contributor <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> .
<https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Agent> .
<https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdfs:label "Not provided" .
<https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> aocat:has_name "Not provided" .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s rdf:type aocat:AO_Individual_Data_Resource .
MINUS {
?s rdf:type aocat:AO_Individual_Data_Resource .
?s aocat:has_contributor ?agent .
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:was_issued ?created_on .
?s aocat:was_modified ?created_on .
}
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport>
WHERE {
?s rdf:type aocat:AO_Collection .
?s aocat:was_created_on ?created_on .
MINUS {
?s rdf:type aocat:AO_Collection .
?s aocat:was_issued ?issued .
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:was_issued ?coll_issued .
?s aocat:was_modified ?coll_modified .
}
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport>
WHERE {
?s rdf:type aocat:AO_Individual_Data_Resource .
?s aocat:is_part_of ?coll .
?coll aocat:was_issued ?coll_issued .
?coll aocat:was_modified ?coll_modified .
MINUS {
?s rdf:type aocat:AO_Individual_Data_Resource .
?s aocat:was_issued ?issued .
?s aocat:was_modified ?modified .
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:has_native_subject <https://ariadne-infrastructure.eu/aocat/Concept/nara/NOT_PROVIDED> .
<https://ariadne-infrastructure.eu/aocat/Concept/nara/NOT_PROVIDED> skos:prefLabel "Not provided" .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s rdf:type aocat:AO_Individual_Data_Resource .
MINUS {
?s rdf:type aocat:AO_Individual_Data_Resource .
?s aocat:has_native_subject ?ns .
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s aocat:has_spatial_coverage <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> .
<https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Spatial_Region> .
<https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> rdfs:label "Name not provided" .
<https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> aocat:has_place_name "Name not provided" .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?s rdf:type aocat:AO_Individual_Data_Resource .
MINUS {
?s rdf:type aocat:AO_Individual_Data_Resource .
?s aocat:has_spatial_coverage ?spatialRegion .
?spatialRegion aocat:has_place_name ?placeName .
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
PREFIX time: <http://www.w3.org/2006/time#>
PREFIX periodo: <http://n2t.net/ark:/99152/p0v#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/ariadneplus::nara::periodoplus> {
?temporal aocat:has_period ?periodO .
?temporal aocat:from ?temporalFrom .
?temporal aocat:until ?temporalUntil .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?temporal aocat:has_native_period ?native_period .
?native_period skos:prefLabel ?native_label .
optional {
GRAPH <https://ariadne-infrastructure.eu/ariadneplus::nara::periodo> {
?periodO skos:altLabel ?native_label .
?periodO time:intervalStartedBy / time:hasDateTimeDescription / periodo:earliestYear ?temporalFrom .
?periodO time:intervalFinishedBy / time:hasDateTimeDescription / periodo:latestYear ?temporalUntil .
}
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
PREFIX time: <http://www.w3.org/2006/time#>
PREFIX periodo: <http://n2t.net/ark:/99152/p0v#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/ariadneplus::nara::periodoplus> {
?temporal aocat:has_period ?periodO .
?temporal aocat:from ?temporalFrom .
?temporal aocat:until ?temporalUntil .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?temporal aocat:has_native_period ?native_period .
?native_period skos:prefLabel ?native_label .
optional {
GRAPH <https://ariadne-infrastructure.eu/ariadneplus::nara::periodo> {
?periodO skos:altLabel ?native_label .
?periodO time:intervalStartedBy / time:hasDateTimeDescription / time:year ?temporalFrom .
?periodO time:intervalFinishedBy / time:hasDateTimeDescription / time:year ?temporalUntil .
}
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
PREFIX time: <http://www.w3.org/2006/time#>
PREFIX periodo: <http://n2t.net/ark:/99152/p0v#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/ariadneplus::nara::periodoplus> {
?temporal aocat:has_period ?periodO .
?temporal aocat:from ?temporalFrom .
?temporal aocat:until ?temporalUntil .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport> {
?temporal aocat:has_native_period ?native_period .
?native_period skos:prefLabel ?native_label .
optional {
GRAPH <https://ariadne-infrastructure.eu/ariadneplus::nara::periodo> {
?periodO skos:altLabel ?native_label .
?periodO time:intervalStartedBy / time:hasDateTimeDescription / time:year ?temporalFrom .
?periodO time:intervalFinishedBy / time:hasDateTimeDescription / periodo:latestYear ?temporalUntil .
}
}
}
};
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/ariadneplus::nara::aatplus> {
?record aocat:has_derived_subject ?aat_subject .
}
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::aat>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::nara::fieldworkreport>
WHERE {
{
?record aocat:has_native_subject ?native_subject .
?aat_native_subject skos:exactMatch ?aat_subject .
bind (IRI(replace( str(?aat_native_subject), "NARA", "NABUNKEN")) as ?patched_aat_native_subject)
filter(?native_subject=?patched_aat_native_subject)
}
union
{
?record aocat:has_native_subject ?native_subject .
?aat_native_subject skos:broadMatch ?aat_subject .
bind (IRI(replace( str(?aat_native_subject), "NARA", "NABUNKEN")) as ?patched_aat_native_subject)
filter(?native_subject=?patched_aat_native_subject)
}
union
{
?record aocat:has_native_subject ?native_subject .
?aat_native_subject skos:closeMatch ?aat_subject .
bind (IRI(replace( str(?aat_native_subject), "NARA", "NABUNKEN")) as ?patched_aat_native_subject)
filter(?native_subject=?patched_aat_native_subject)
}
union
{
?record aocat:has_native_subject ?native_subject .
?aat_native_subject skos:narrowMatch ?aat_subject .
bind (IRI(replace( str(?aat_native_subject), "NARA", "NABUNKEN")) as ?patched_aat_native_subject)
filter(?native_subject=?patched_aat_native_subject)
}
union
{
?record aocat:has_native_subject ?native_subject .
?aat_native_subject skos:relatedMatch ?aat_subject .
bind (IRI(replace( str(?aat_native_subject), "NARA", "NABUNKEN")) as ?patched_aat_native_subject)
filter(?native_subject=?patched_aat_native_subject)
}
};
Reference in New Issue View Git Blame Copy Permalink