AriadnePlus/dnet-ariadneplus-graphdb-publisher/src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/LNEC/ordered_sparql_insert_LNEC_collection.sparql

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::CollectionInfo> {
          ?s	aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> .
          <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Concept> .
          <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> skos:prefLabel "collection"
        }
    }
    WHERE {
        GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::CollectionInfo> {
            ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
            MINUS {
                ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
                ?s	aocat:has_type ?t .
            }
        }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::CollectionInfo> {
        ?s aocat:was_issued ?created_on .
        ?s aocat:was_modified ?created_on .
    }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::CollectionInfo>
WHERE {
    ?s rdf:type aocat:AO_Collection .
    ?s aocat:was_created_on ?created_on .
    MINUS {
        ?s rdf:type aocat:AO_Collection .
        ?s aocat:was_issued ?issued .
    }
};

  PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
  PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
  INSERT {
      GRAPH <https://ariadne-infrastructure.eu/ariadneplus::lnec::aatplus> {
          ?record aocat:has_derived_subject ?aat .
      }
  }
  WHERE {
          GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::CollectionInfo> {
               ?record aocat:has_native_subject ?ns.
                  GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::aat> {
                      {
                      ?ns skos:closeMatch ?aat .
                      }
                      union
                      {
                      ?ns skos:exactMatch ?aat .
                      }
                      union
                      {
                      ?ns skos:narrowMatch ?aat .
                      }
                      union
                      {
                      ?ns skos:broadMatch ?aat .
                      }
                  }
              }
  };

    PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
    PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
    PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
    PREFIX owl: <http://www.w3.org/2002/07/owl#>
    PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
    PREFIX time: <http://www.w3.org/2006/time#>
    PREFIX periodo: <http://n2t.net/ark:/99152/p0v#>
    INSERT {
     GRAPH <https://ariadne-infrastructure.eu/ariadneplus::lnec::periodoplus> {
         ?temporal aocat:has_period ?periodO .
         ?temporal aocat:from ?temporalFrom .
         ?temporal aocat:until ?temporalUntil .
     }
    }
    WHERE {
     GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::CollectionInfo> {
           ?temporal aocat:has_native_period ?native_period .
            ?native_period skos:prefLabel ?native_label .
            optional {
                GRAPH <https://ariadne-infrastructure.eu/ariadneplus::lnec::periodo> {
                    ?periodO skos:altLabel ?native_label .
                    ?periodO time:intervalStartedBy / time:hasDateTimeDescription / time:year ?temporalFrom .
                    ?periodO time:intervalFinishedBy / time:hasDateTimeDescription / time:year ?temporalUntil .
                }
           }
       }
    };

        PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
        PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
        PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
        PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
        PREFIX owl: <http://www.w3.org/2002/07/owl#>
        PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
        PREFIX time: <http://www.w3.org/2006/time#>
        PREFIX periodo: <http://n2t.net/ark:/99152/p0v#>
        INSERT {
         GRAPH <https://ariadne-infrastructure.eu/ariadneplus::lnec::periodoplus> {
             ?temporal aocat:from ?temporalFrom .
             ?temporal aocat:until ?temporalUntil .
         }
        }
        WHERE {
         GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::lnec::CollectionInfo> {
               ?s aocat:has_temporal_coverage ?temporal .
               ?temporal aocat:from ?temporalFrom .
               ?temporal aocat:until ?temporalUntil .
           }
        };