AriadnePlus/dnet-ariadneplus-graphdb-publisher/src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/DANS/ordered_sparql_insert_dans_easy.sparql

ADD SILENT <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::pan_images> TO <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy>;

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?record aocat:has_responsible ?legalResponsible .
        ?record aocat:has_owner ?owner .
        ?record aocat:has_publisher ?publisher .
    }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::CollectionInfo>
WHERE {
	?record aocat:is_part_of ?collection .
    ?collection aocat:has_responsible ?legalResponsible .
    ?collection aocat:has_owner ?owner .
    ?collection aocat:has_publisher ?publisher .
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?record aocat:has_ARIADNE_subject ?coll_value .
    }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::CollectionInfo>
WHERE {
	?record aocat:is_part_of ?collection .
    ?collection aocat:has_ARIADNE_subject ?coll_value .
    MINUS {
        ?record	aocat:has_ARIADNE_subject ?rec_value .
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?s aocat:was_issued ?created_on .
    }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy>
WHERE {
    ?s rdf:type aocat:AO_Individual_Data_Resource .
    ?s aocat:was_created_on ?created_on .
    MINUS {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        ?s aocat:was_issued ?issued .
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
          ?s	aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> .
          <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Concept> .
          <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> skos:prefLabel "provided record"
        }
    }
    WHERE {
        GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
                ?s	aocat:has_type ?t .
            }
        }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
      ?s	aocat:has_spatial_coverage <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> .
      <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Spatial_Region> .
      <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> rdfs:label "Name not provided" .
      <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> aocat:has_place_name "Name not provided" .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            ?s	aocat:has_spatial_coverage ?spatialRegion .
            ?spatialRegion  aocat:has_place_name ?placeName .
        }
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
      ?s	aocat:has_contributor <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> .
      <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Agent> .
      <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> rdfs:label "Not provided" .
      <https://ariadne-infrastructure.eu/aocat/Agent/NOTPROVIDED> aocat:has_name "Not provided" .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            ?s	aocat:has_contributor ?agent .
        }
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?s aocat:was_modified ?created_on .
    }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy>
WHERE {
    ?s rdf:type aocat:AO_Individual_Data_Resource .
    ?s aocat:was_created_on ?created_on .
    MINUS {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        ?s aocat:was_modified ?modified .
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?isoLangRef skos:prefLabel ?lang .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        ?s	aocat:has_language ?isoLangRef .
            MINUS {
                ?s rdf:type aocat:AO_Individual_Data_Resource .
                ?s	aocat:has_language ?isoLangRef .
                ?isoLangRef skos:prefLabel ?p .
            }
        bind (strafter(str(?isoLangRef),"iso639-1/") as ?lang)
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?s	aocat:has_language <http://lexvo.org/id/iso639-3/und> .
        <http://lexvo.org/id/iso639-3/und> skos:prefLabel "und" .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            ?s	aocat:has_language ?ns .
        }
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?c aocat:has_name ?l .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        ?s aocat:has_creator ?c .
        ?c rdfs:label ?l .
        MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            ?s aocat:has_creator ?c .
            ?c aocat:has_name ?n .
        }
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?c aocat:has_name ?l .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        ?s aocat:has_contributor ?c .
        ?c rdfs:label ?l .
        MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            ?s aocat:has_contributor ?c .
            ?c aocat:has_name ?n .
        }
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/ariadneplus::dans::aatplus> {
        ?record aocat:has_derived_subject ?aat .
    }
}
WHERE {
            graph <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
            ?record aocat:has_native_subject ?ns_label .
                bind(strafter(str(?ns_label),"Match: ") as ?m)
                filter(str(?m)=str(?aat_label))
                }
            graph <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::aat> {
                {
                            ?subject skos:broadMatch ?aat	.
            ?aat skos:prefLabel ?aat_label .
                }
                union
                {
                            ?subject skos:exactMatch ?aat	.
            ?aat skos:prefLabel ?aat_label .
                }
                union
                {
                            ?subject skos:closeMatch ?aat	.
            ?aat skos:prefLabel ?aat_label .
                }
                union
                {
                            ?subject skos:narrowMatch ?aat	.
            ?aat skos:prefLabel ?aat_label .
                }
            }
};
    
PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
 PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
 PREFIX time: <http://www.w3.org/2006/time#>
 PREFIX dcterms: <http://purl.org/dc/terms/>
 INSERT {
     GRAPH <https://ariadne-infrastructure.eu/ariadneplus::dans::periodoplus> {
         ?temporal aocat:has_period ?periodO .
         ?temporal aocat:from ?temporalFrom .
         ?temporal aocat:until ?temporalUntil .
     }
 }
 WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::dans::easy> {
       ?temporal aocat:has_native_period ?native_period .
        ?native_period skos:prefLabel ?native_label .
        optional {
            GRAPH <https://ariadne-infrastructure.eu/ariadneplus::dans::periodo> {
                ?periodO skos:altLabel ?native_label .
                ?periodO time:intervalStartedBy / time:hasDateTimeDescription / time:year ?temporalFrom .
                ?periodO time:intervalFinishedBy / time:hasDateTimeDescription / time:year ?temporalUntil .
            }
       }
   }
 };