PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::test> {
        ?s	aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> .
        <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> skos:prefLabel "provided record" .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::test> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
 INSERT {
     GRAPH  <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::test> {
        ?record aocat:was_issued ?x .
     }
 }
 USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::test>
 USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::coll>
 WHERE {
         ?record aocat:is_part_of ?collection .
         ?collection aocat:was_issued ?x .
         MINUS{
            ?record aocat:was_issued ?date
         }
 };

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
INSERT {
  GRAPH  <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::test> {
     ?record aocat:was_modified ?x .
  }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::test>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::coll>
WHERE {
      ?record aocat:is_part_of ?collection .
      ?collection aocat:was_modified ?x .
      MINUS{
         ?record aocat:was_modified ?date
      }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
INSERT {
    GRAPH  <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::test> {
       ?record aocat:has_access_rights ?x .
    }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::test>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::coll>
WHERE {
        ?record aocat:is_part_of ?collection .
        ?collection aocat:has_access_rights ?x .
        MINUS{
           ?record aocat:has_access_rights ?ar
        }
};


PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX time: <http://www.w3.org/2006/time#>
 INSERT {
     GRAPH <https://ariadne-infrastructure.eu/ariadneplus::oslo::periodoplus> {
           ?temporal aocat:has_period ?aat .
           ?temporal aocat:from ?temporalFrom .
           ?temporal aocat:until ?temporalUntil .
     }
 }
 USING <https://ariadne-infrastructure.eu/ariadneplus::oslo::periodo>
 USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::test>
 WHERE {
         ?temporal aocat:has_native_period ?nativePeriod .
         ?nativePeriod skos:prefLabel ?nativeLabel .
         ?aat skos:inScheme <http://n2t.net/ark:/99152/p04h98q> .
         ?aat skos:altLabel ?nativeLabel .
         ?aat time:intervalStartedBy ?intervalStartedBy .
         ?intervalStartedBy time:hasDateTimeDescription ?sdesc .
         ?sdesc time:year ?temporalFrom .
         ?aat time:intervalFinishedBy ?intervalFinishedBy .
         ?intervalFinishedBy time:hasDateTimeDescription ?fdesc .
         ?fdesc time:year ?temporalUntil
 };


 PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
 PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

 INSERT {
  GRAPH <https://ariadne-infrastructure.eu/ariadneplus::oslo::aatplus> {
      ?record aocat:has_derived_subject ?aat_subject .
  }
 }
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::aat>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::oslo::test>
 WHERE {
      {
          ?record aocat:has_native_subject ?native_subject .
          ?aat_native_subject skos:exactMatch ?aat_subject	.
          bind (IRI(concat( "https://ariadne-infrastructure.eu/aocat/Concept/OSLO/", ucase(strafter(str(?native_subject),"UO/")))) as ?uppercase_native_subject)
          filter(?uppercase_native_subject=?aat_native_subject)
      }
      union
      {
          ?record aocat:has_native_subject ?native_subject .
          ?aat_native_subject skos:broadMatch ?aat_subject	.
          bind (IRI(concat( "https://ariadne-infrastructure.eu/aocat/Concept/OSLO/", ucase(strafter(str(?native_subject),"UO/")))) as ?uppercase_native_subject)
          filter(?uppercase_native_subject=?aat_native_subject)
      }
      union
      {
          ?record aocat:has_native_subject ?native_subject .
          ?aat_native_subject skos:closeMatch ?aat_subject	.
          bind (IRI(concat( "https://ariadne-infrastructure.eu/aocat/Concept/OSLO/", ucase(strafter(str(?native_subject),"UO/")))) as ?uppercase_native_subject)
          filter(?uppercase_native_subject=?aat_native_subject)
      }
      union
      {
          ?record aocat:has_native_subject ?native_subject .
          ?aat_native_subject skos:narrowMatch ?aat_subject	.
          bind (IRI(concat( "https://ariadne-infrastructure.eu/aocat/Concept/OSLO/", ucase(strafter(str(?native_subject),"UO/")))) as ?uppercase_native_subject)
          filter(?uppercase_native_subject=?aat_native_subject)
      }
 };