DELETE WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
    <http://openarchaeo.huma-num.fr/federation/sources/chronique> ?p ?o .
    ?s ?x <http://openarchaeo.huma-num.fr/federation/sources/chronique>
}
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT DATA{
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
      <http://lexvo.org/id/iso639-2/eng> skos:prefLabel "eng" .
      <http://lexvo.org/id/iso639-2/fra> skos:prefLabel "fre" .
      <https://ariadne-infrastructure.eu/aocat/Concept/AO_Subject/Fieldwork> skos:prefLabel "Fieldwork"@en .
      <https://ariadne-infrastructure.eu/aocat/Concept/AO_Subject/Fieldwork%20archive> skos:prefLabel "Fieldwork archive"@en .
      <https://ariadne-infrastructure.eu/aocat/Concept/AO_Subject/Fieldwork%20report> skos:prefLabel "Fieldwork report"@en .
      <https://ariadne-infrastructure.eu/aocat/Concept/AO_Subject/Site%2Fmonument> skos:prefLabel "Site/monument"@en .
      <https://ariadne-infrastructure.eu/aocat/Concept/AO_Subject/Inscription> skos:prefLabel "Inscription"@en .
      <https://ariadne-infrastructure.eu/aocat/Concept/AO_Subject/Artefact> skos:prefLabel "Artefact"@en .
      <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/Collection> skos:prefLabel "collection" .
      <http://openarchaeo.huma-num.fr> aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> .
      <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Concept> .
      <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> skos:prefLabel "collection"

    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
        ?s	aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> .
        <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> skos:prefLabel "provided record" .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            ?s	aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> .
        }
    }
};

PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
      ?s aocat:is_part_of ?collection
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
        ?collection rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
        ?collection aocat:has_part ?s
    }
};


PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
      ?s	aocat:has_spatial_coverage <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> .
      <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Spatial_Region> .
      <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> rdfs:label "Place not provided" .
      <https://ariadne-infrastructure.eu/aocat/Place/NOTPROVIDED> aocat:has_place_name "Place not provided" .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
        MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            ?s	aocat:has_spatial_coverage ?spatialRegion .
        }
    }
};


PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
      ?spatialRegion rdfs:label "Place name not provided" .
      ?spatialRegion aocat:has_place_name "Place name not provided" .
    }
}
WHERE {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
        ?s rdf:type aocat:AO_Individual_Data_Resource .
         ?s	aocat:has_spatial_coverage ?spatialRegion .
        MINUS {
            ?s rdf:type aocat:AO_Individual_Data_Resource .
            ?s	aocat:has_spatial_coverage ?spatialRegion .
            ?spatialRegion aocat:has_place_name ?placeName .
        }
    }
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
          ?ns skos:prefLabel ?nstitle .
        }
    }
    WHERE {
        GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
            ?s aocat:has_native_subject ?ns .
            ?ns aocat:has_title ?nstitle
        }
};

 PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
 PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
 INSERT {
    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
    ?s aocat:has_landing_page ?lpResource .
    ?lpResource rdfs:label ?url
    }

 }
 WHERE {
 GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl> {
    ?s aocat:has_landing_page ?url .
    BIND (IRI(?url) as ?lpResource)
    }
 };


PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
INSERT {
 GRAPH <https://ariadne-infrastructure.eu/ariadneplus::openarchaeo::aatplus> {
     ?s aocat:has_derived_subject ?aat .
 }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::aat>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl>
WHERE {
          {
            ?s aocat:has_native_subject ?native_subject .
            ?concept owl:sameAs ?native_subject .
            ?concept skos:exactMatch ?aat .
          }
          union
          {
              ?s aocat:has_native_subject ?native_subject .
              ?concept owl:sameAs ?native_subject .
              ?concept skos:broadMatch ?aat .
          }
          union
          {
            ?s aocat:has_native_subject ?native_subject .
            ?concept owl:sameAs ?native_subject .
            ?concept skos:closeMatch ?aat .
          }
          union
          {
            ?s aocat:has_native_subject ?native_subject .
            ?concept owl:sameAs ?native_subject .
            ?concept skos:narrowMatch ?aat .
          }
};

   PREFIX dcterms: <http://purl.org/dc/terms/>
   PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
   INSERT {
       GRAPH <https://ariadne-infrastructure.eu/ariadneplus::openarchaeo::periodo> {
               ?periodO ?pred ?o .
               ?o ?pred2 ?o2 .
               ?o2 ?pred3 ?o3 .
           }
       }
       WHERE {
           GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl>{
                ?temporal aocat:has_period ?periodO .
           }
           GRAPH <https://ariadne-infrastructure.eu/ariadne/periodo> {
               ?periodO ?pred ?o .
               optional {
                   ?o ?pred2 ?o2 .
                   optional {
                       ?o2 ?pred3 ?o3 .
                   }
               }
           }
       };

PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX ariadneplus: <https://ariadne-infrastructure.eu/aocat/>
PREFIX time: <http://www.w3.org/2006/time#>
INSERT {
 GRAPH <https://ariadne-infrastructure.eu/ariadneplus::openarchaeo::periodoplus> {
     ?temporal aocat:has_period ?periodO .
     ?temporal aocat:from ?temporalFrom .
     ?temporal aocat:until ?temporalUntil .
 }
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::openarchaeo::ttl>
USING <https://ariadne-infrastructure.eu/ariadneplus::openarchaeo::periodo>
WHERE {
         ?temporal aocat:has_period ?periodO .
         ?periodO time:intervalStartedBy ?intervalStartedBy .
         ?intervalStartedBy  time:hasDateTimeDescription ?startTimeDescr .
         ?startTimeDescr time:year ?temporalFrom .
         ?periodO time:intervalFinishedBy ?intervalFinishedBy .
         ?intervalFinishedBy  time:hasDateTimeDescription ?finishedTimeDescr .
         ?finishedTimeDescr time:year ?temporalUntil .
};