#PERIODO ENRICHMENT

 # WHEN THE OLD ARIADNE PERIODO COLLECTION IS INVOLVED DO THIS FIRST TO PUT THE TRIPLES IN THE PROPER NAMED GRAPH

 PREFIX dcterms: <http://purl.org/dc/terms/>
 INSERT {
     GRAPH <https://ariadne-infrastructure.eu/ariadneplus::<provider>::periodo> {
             ?periodO ?pred ?o .
             ?o ?pred2 ?o2 .
             ?o2 ?pred3 ?o3 .
         }
     }
     WHERE {
         GRAPH <https://ariadne-infrastructure.eu/ariadne/periodo> {
             ?periodO dcterms:spatial <http://www.wikidata.org/entity/SPATIALCODE> .
             ?periodO ?pred ?o .
             optional {
                 ?o ?pred2 ?o2 .
                 optional {
                     ?o2 ?pred3 ?o3 .
                 }
             }
         }
     };

 PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
 PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
 PREFIX time: <http://www.w3.org/2006/time#>
 INSERT {
     GRAPH <https://ariadne-infrastructure.eu/ariadneplus::<provider>::periodoplus> {
         ?temporal aocat:has_period ?periodO .
         ?temporal aocat:from ?temporalFrom .
         ?temporal aocat:until ?temporalUntil .
     }
 }
 WHERE {
 	GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::<provider>::<coll>> {
       ?temporal aocat:has_native_period ?native_period .
        ?native_period skos:prefLabel ?native_label .
        optional {
            GRAPH <https://ariadne-infrastructure.eu/ariadneplus::<provider>::periodo> {
                ?periodO skos:altLabel ?native_label .
                ?periodO skos:inScheme	<PROVIDER_PERIODO_SCHEME_URL> .
                ?periodO time:intervalStartedBy ?intervalStartedBy .
                ?intervalStartedBy skos:prefLabel ?temporalFrom .
                ?periodO time:intervalFinishedBy ?intervalFinishedBy .
                ?intervalFinishedBy skos:prefLabel ?temporalUntil .
            }
       }
   }
 };