D-Net
/
AriadnePlus
4
0
Fork 0
Code Issues Pull Requests Releases Wiki Activity

enrichment for iavp farms

This commit is contained in:
Enrico Ottonello 2022-03-29 12:16:13 +02:00
parent 9851afe6e0
commit ef1de72687
1 changed files with 107 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

107
dnet-ariadneplus-graphdb-publisher/src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/IAVP/ordered_sparql_insert_IAVP_farms.sparql Normal file
View File

@ -0,0 +1,107 @@
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::farms> {
?record aocat:was_issued ?issued .
?record aocat:was_modified ?modified .
?record aocat:has_responsible ?legalResponsible .
?legalResponsible aocat:has_name ?resp .
?record aocat:has_owner ?owner .
?owner aocat:has_name ?own .
?record aocat:has_access_rights ?accessRights .
?record aocat:has_language ?lang .
?lang skos:prefLabel ?langL
}
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::farms>
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::collection>
WHERE {
?record aocat:is_part_of ?collection .
?collection aocat:has_original_id "Communist agricultural system db" .
?collection aocat:was_issued ?issued .
?collection aocat:was_modified ?modified .
?collection aocat:has_responsible ?legalResponsible .
?legalResponsible aocat:has_name ?resp .
?collection aocat:has_owner ?owner .
?owner aocat:has_name ?own .
?collection aocat:has_access_rights ?accessRights .
?collection aocat:has_language ?lang .
?lang skos:prefLabel ?langL
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::farms> {
?s aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> .
<https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Concept> .
<https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/provided%20record> skos:prefLabel "provided record"
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::farms> {
?s rdf:type aocat:AO_Individual_Data_Resource .
MINUS {
?s rdf:type aocat:AO_Individual_Data_Resource .
?s aocat:has_type ?t .
}
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/ariadneplus::iavp::aatplus> {
?record aocat:has_derived_subject ?derived_subject .
}
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::farms>
WHERE {
{
?record aocat:has_derived_subject ?derived_subject .
}
};
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::aat> {
?derived_subject skos:prefLabel ?dslabel .
}
}
USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::farms>
WHERE {
{
?record aocat:has_derived_subject ?derived_subject .
?derived_subject skos:prefLabel ?dslabel .
}
};
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
PREFIX time: <http://www.w3.org/2006/time#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX periodo: <http://n2t.net/ark:/99152/p0v#>
INSERT {
GRAPH <https://ariadne-infrastructure.eu/ariadneplus::iavp::periodoplus> {
?temporal aocat:has_period ?periodO .
?temporal aocat:from ?temporalFrom .
?temporal aocat:until ?temporalUntil .
}
}
WHERE {
GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::iavp::farms> {
?temporal aocat:has_period ?periodO .
optional {
GRAPH <https://ariadne-infrastructure.eu/ariadneplus::iavp::periodo> {
?periodO skos:altLabel ?native_label .
?periodO time:intervalStartedBy / time:hasDateTimeDescription / periodo:earliestYear ?temporalFrom .
?periodO time:intervalFinishedBy / time:hasDateTimeDescription / time:year ?temporalUntil .
}
}
}
};