diff --git a/dnet-ariadneplus-graphdb-publisher/src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/INFN/ordered_sparql_insert_infn.sparql b/dnet-ariadneplus-graphdb-publisher/src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/INFN/ordered_sparql_insert_infn.sparql
new file mode 100644
index 0000000..18833db
--- /dev/null
+++ b/dnet-ariadneplus-graphdb-publisher/src/main/resources/eu/dnetlib/ariadneplus/sparql/enrich/INFN/ordered_sparql_insert_infn.sparql
@@ -0,0 +1,86 @@
+PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+INSERT {
+    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::infn::torino> {
+        ?s aocat:was_issued ?created_on .
+        ?s aocat:was_modified ?created_on .
+    }
+}
+USING <https://ariadne-infrastructure.eu/api_________::ariadne_plus::infn::torino>
+WHERE {
+    ?s rdf:type aocat:AO_Collection .
+    ?s aocat:was_created_on ?created_on .
+    MINUS {
+        ?s rdf:type aocat:AO_Collection .
+        ?s aocat:was_created_on ?created_on .
+        ?s aocat:was_issued ?issued .
+        ?s aocat:was_modified ?modified .
+    }
+};
+
+PREFIX aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
+PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+INSERT {
+    GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::infn::torino> {
+          ?s	aocat:has_type <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> .
+          <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Concept> .
+          <https://ariadne-infrastructure.eu/aocat/Concept/AO_Type/collection> skos:prefLabel "collection"
+        }
+    }
+    WHERE {
+        GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::infn::torino> {
+            ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
+            MINUS {
+                ?s rdf:type <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/AO_Collection> .
+                ?s	aocat:has_type ?t .
+            }
+        }
+};
+
+PREFIX dcterms: <http://purl.org/dc/terms/>
+INSERT {
+    GRAPH <https://ariadne-infrastructure.eu/ariadneplus::infn::periodo> {
+            ?periodO ?pred ?o .
+            ?o ?pred2 ?o2 .
+            ?o2 ?pred3 ?o3 .
+        }
+    }
+    WHERE {
+        GRAPH <https://ariadne-infrastructure.eu/ariadne/periodo> {
+        ?periodO <http://n2t.net/ark:/99152/p0v#spatialCoverageDescription> "Italy less Sicily, Sardinia, Tuscany, Umbria" .
+            ?periodO ?pred ?o .
+            optional {
+                ?o ?pred2 ?o2 .
+                optional {
+                    ?o2 ?pred3 ?o3 .
+                }
+            }
+        }
+    };
+
+PREFIX  skos: <http://www.w3.org/2004/02/skos/core#>
+PREFIX  aocat: <https://www.ariadne-infrastructure.eu/resource/ao/cat/1.1/>
+PREFIX time: <http://www.w3.org/2006/time#>
+PREFIX dcterms: <http://purl.org/dc/terms/>
+INSERT {
+ GRAPH <https://ariadne-infrastructure.eu/ariadneplus::infn::periodoplus> {
+     ?temporal aocat:has_period ?period .
+     ?temporal aocat:from ?temporalFrom .
+     ?temporal aocat:until ?temporalUntil .
+ }
+}
+WHERE {
+GRAPH <https://ariadne-infrastructure.eu/api_________::ariadne_plus::infn::torino>  {
+    ?temporal aocat:has_period ?period .
+     optional {
+         GRAPH <https://ariadne-infrastructure.eu/ariadneplus::infn::periodo> {
+             ?period skos:altLabel ?native_label .
+             ?period time:intervalStartedBy / time:hasDateTimeDescription / time:year ?temporalFrom .
+             ?period time:intervalFinishedBy / time:hasDateTimeDescription / time:year ?temporalUntil .
+         }
+    }
+    }
+};
\ No newline at end of file